// Yellowboy

ACTOR Yellowboy : IDMWeapon
{
	Weapon.SelectionOrder 800
	Weapon.SlotNumber 2
	Weapon.PreferredSkin "CarbineMarine"
	Weapon.AmmoUse 10
	Weapon.AmmoGive 50
	Weapon.AmmoType "IDMClip"
	Weapon.Kickback 200
	Inventory.PickupMessage "Yellowboy!"
	Obituary "%o was sniped by %k's Yellowboy."
	AttackSound "weapons/wchfire"
	Tag "Yellowboy"
	Decal Bulletchip
	Damagetype "Bullet"
	+WEAPON.NOAUTOAIM
	+WEAPON.ALLOW_WITH_RESPAWN_INVUL
	+WEAPON.NOLMS
	States
	{
	Ready:
      WINC A 1 A_WeaponReady
      Loop
	Deselect:
      WINC A 0 A_Lower
      WINC A 0 A_Lower
      WINC A 1 A_Lower
      Loop
	Select:
	  TNT1 A 0 A_PlaySound("weapons/wswitch",CHAN_WEAPON)
	Sloop:
      WINC A 0 A_Raise
      WINC A 0 A_Raise
      WINC A 1 A_Raise
      Loop
	Fire:
      WINC A 2
	Normal:
	  TNT1 A 0 A_JumpIfInventory("PowerIDMWeaponLevel2",1,"Level2")
	  TNT1 A 0 A_JumpIfInventory("PowerQuadDamage",1,"Quad")
      TNT1 A 0 A_FireBullets(0, 0, 1, random(100,200), "IDMBulletPuff", FBF_NORANDOM | FBF_USEAMMO)
	  Goto FireEnd
	Level2:
	  WINC A 0 A_JumpIfInventory("PowerQuadDamage",1,"QuadLevel2")
      WINC B 0 A_RailAttack(random(100,200),0,1,none,"Orange",0,0,"PiercePuff")
	  Goto FireEnd
	QuadLevel2:
	  TNT1 A 0 A_Playsound("misc/qdmg",CHAN_AUTO,1)
	  Goto Level2+1
	Quad:
	  TNT1 A 0 A_Playsound("misc/qdmg",CHAN_AUTO,1)
	  WINC B 0 A_FireBullets(0, 0, 1, random(100,200), "ExtremePuff", FBF_NORANDOM | FBF_USEAMMO)
	FireEnd:
	  WINC B 6 A_GunFlash
      WINC C 5
      WINC D 4 A_Playsound ("weapons/wchlevr")
      WINC E 5
      WINC DC 4
      WINC A 2
      Goto Ready
	Flash:
      LAMZ B 3 Bright A_Light1
      LAMZ A 2 Bright A_Light2
	  Goto LightDone
	Spawn:
      WHCE A -1 Bright
      Stop
	}
}